Sub LanguageSetUS()
' Paul Beverley - Version 09.04.23
' Sets language as US English

' If you want all the styles to be language-set as well,
' make it true:
setStyleLanguage = False
' setStyleLanguage = True

myLanguage = wdEnglishUS
ActiveDocument.Content.LanguageID = myLanguage
For Each aStory In ActiveDocument.StoryRanges
  Do
    aStory.LanguageID = myLanguage
    If aStory.NextStoryRange Is Nothing Then
      MoreStoryRanges = False
    Else
      MoreStoryRanges = True
      Set aStory = aStory.NextStoryRange
    End If
  Loop While MoreStoryRanges
Next aStory
If setStyleLanguage = True Then
  For i = 1 To ActiveDocument.Styles.Count
    Set sty = ActiveDocument.Styles(i)
    If sty.Type = wdStyleTypeParagraph Then _
         sty.LanguageID = myLanguage
  Next i
End If
If ActiveDocument.Shapes.Count > 0 Then
  For Each shp In ActiveDocument.Shapes
    If shp.Type <> 24 And shp.Type <> 3 Then
      If shp.TextFrame.HasText Then
        shp.TextFrame.TextRange.LanguageID = myLanguage
      End If
    End If
  Next
End If
ActiveDocument.Styles(wdStyleNormal).LanguageID = myLanguage
ActiveDocument.Styles(wdStyleCommentText).LanguageID = myLanguage
ActiveDocument.Styles("Balloon Text").LanguageID = myLanguage
End Sub